Сделал автоустановку на основе оригинального инсталлятора:
Код:
@Echo off
CD /D "%~dp0"
if exist "%ProgramFiles%\Winamp\UninstWA.exe" (
echo Uninstall old Winamp
taskkill /IM winampa.exe /T /F >nul
taskkill /IM winamp.exe /T /F >nul
"%ProgramFiles%\Winamp\UninstWA.exe" /S
ping -n 20 127.0.0.1 >nul
)
echo Install Winamp...
winamp5621_full_emusic-7plus_ru-ru.exe /S /install=SDQRA
rem S=start menu icons, F=file association, Q=quicklaunch icon, D=desktop icon, R=fake registration, A=run winamp agent/set default
echo Copy predifined config files
copy /Y studio.xnf %AppData%\Winamp\*.* >nul
copy /Y winamp.ini %AppData%\Winamp\*.* >nul
echo Register WinAmp Pro
rem Вставте свои регистрационные данные тут
reg add "HKLM\SOFTWARE\Nullsoft\Winamp" /v "regname" /t REG_SZ /d "" /f >nul
reg add "HKLM\SOFTWARE\Nullsoft\Winamp" /v "regkey" /t REG_SZ /d "" /f >nul
echo Uninstall eMusic
"%ProgramFiles%\Winamp\eMusic\Uninst-eMusic-promotion.exe" /S
ping -n 5 127.0.0.1 >nul
rd "%ProgramFiles%\Winamp\eMusic" >nul
echo Uninstall Winamp Toolbar
"%ProgramFiles%\Winamp Toolbar\uninstall.exe" /S
ping -n 5 127.0.0.1 >nul
echo register file association
"%ProgramFiles%\Winamp\winamp.exe" /UNREG
rem To register everything Audio filetypes, Video filetypes, Cd, Needreg, Dircontextmenus, playLists
"%ProgramFiles%\Winamp\winamp.exe" /REG=ACNDL
echo Register WinAmp Agent
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "WinampAgent" /t REG_SZ /d """"%ProgramFiles%\Winamp\winampa.exe"""" /f >nul
exit
Все срабатывает отлично - кроме одного - не создается папке в меню пуск.
Проверка показала, что и при запуске просто
Код:
winamp5621_full_emusic-7plus_ru-ru.exe /S
Папка в меню пуск тоже не создается.
Какие будут идеи по этому поводу?
Сторонний репак применять не хочется.